# SPDX-License-Identifier: MIT
# chirpmodem C library: installable build.
#
#   cmake -S . -B build -DCMAKE_BUILD_TYPE=Release
#   cmake --build build -j
#   ctest --test-dir build
#   cmake --install build --prefix /usr/local
#
# Consumers: find_package(chirpmodem) -> chirpmodem::chirpmodem (shared) or
# chirpmodem::chirpmodem_static, or pkg-config chirpmodem.
cmake_minimum_required(VERSION 3.13)
project(chirpmodem VERSION 0.1.0 DESCRIPTION "Chirp spread-spectrum modem, format v1" LANGUAGES C)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)

option(CHIRPMODEM_BUILD_TOOLS "Build cm_tx, cm_rx and the conformance tools" ON)
option(CHIRPMODEM_BUILD_TESTS "Build the API tests" ON)
option(CHIRPMODEM_BUILD_EXAMPLES "Build examples/loopback" ON)
option(CHIRPMODEM_NATIVE "Optimise for this machine (-march=native); off for packages" OFF)

if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  set(CMAKE_BUILD_TYPE Release CACHE STRING "" FORCE)
endif()

set(CHIRPMODEM_SOURCES
  src/cm_util.c src/cm_ldpc.c src/cm_codec.c src/cm_frame.c src/cm_fft.c src/cm_rx.c
  src/cm_stream.c src/cm_tx.c)

# one set of objects for both libraries
add_library(chirpmodem_obj OBJECT ${CHIRPMODEM_SOURCES})
set_target_properties(chirpmodem_obj PROPERTIES
  C_STANDARD 99 C_STANDARD_REQUIRED ON C_EXTENSIONS OFF
  POSITION_INDEPENDENT_CODE ON C_VISIBILITY_PRESET hidden)
target_include_directories(chirpmodem_obj PRIVATE include src)
target_compile_definitions(chirpmodem_obj PRIVATE _DEFAULT_SOURCE CHIRPMODEM_BUILDING CHIRPMODEM_SHARED)
if(CMAKE_C_COMPILER_ID MATCHES "GNU|Clang")
  target_compile_options(chirpmodem_obj PRIVATE -Wall -Wextra)
  if(CHIRPMODEM_NATIVE)
    target_compile_options(chirpmodem_obj PRIVATE -march=native)
  endif()
endif()

find_library(MATH_LIBRARY m)

add_library(chirpmodem SHARED $<TARGET_OBJECTS:chirpmodem_obj>)
add_library(chirpmodem_static STATIC $<TARGET_OBJECTS:chirpmodem_obj>)
foreach(t chirpmodem chirpmodem_static)
  target_include_directories(${t} PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
  if(MATH_LIBRARY)
    target_link_libraries(${t} PUBLIC ${MATH_LIBRARY})
  endif()
endforeach()
target_compile_definitions(chirpmodem INTERFACE CHIRPMODEM_SHARED)
set_target_properties(chirpmodem PROPERTIES
  VERSION ${PROJECT_VERSION} SOVERSION ${PROJECT_VERSION_MAJOR}
  PUBLIC_HEADER include/chirpmodem.h)
if(NOT WIN32)
  set_target_properties(chirpmodem_static PROPERTIES OUTPUT_NAME chirpmodem)
endif()
add_library(chirpmodem::chirpmodem ALIAS chirpmodem)
add_library(chirpmodem::chirpmodem_static ALIAS chirpmodem_static)

if(CHIRPMODEM_BUILD_TOOLS)
  # cm_tx / cm_rx use only the public API; the conformance tools need the internals
  foreach(tool cm_tx cm_rx)
    add_executable(${tool} tools/${tool}_main.c)
    target_link_libraries(${tool} PRIVATE chirpmodem)
    set_target_properties(${tool} PROPERTIES C_STANDARD 99)
    target_compile_definitions(${tool} PRIVATE _DEFAULT_SOURCE)
  endforeach()
  foreach(tool cm_txvec cm_rxvec)
    add_executable(${tool} tools/${tool}.c)
    target_link_libraries(${tool} PRIVATE chirpmodem_static)
    target_include_directories(${tool} PRIVATE src)
    set_target_properties(${tool} PROPERTIES C_STANDARD 99)
    target_compile_definitions(${tool} PRIVATE _DEFAULT_SOURCE)
  endforeach()
  # installed tools find the library next to them wherever the tree is installed
  if(APPLE)
    set_target_properties(cm_tx cm_rx PROPERTIES INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
  elseif(UNIX)
    set_target_properties(cm_tx cm_rx PROPERTIES INSTALL_RPATH "$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
  endif()
  install(TARGETS cm_tx cm_rx RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
endif()

if(CHIRPMODEM_BUILD_TESTS)
  enable_testing()
  find_package(Threads)
  add_executable(test_api tests/test_api.c)
  target_link_libraries(test_api PRIVATE chirpmodem Threads::Threads)
  set_target_properties(test_api PROPERTIES C_STANDARD 99)
  target_compile_definitions(test_api PRIVATE _DEFAULT_SOURCE)
  add_test(NAME api COMMAND test_api)
  include(CheckLanguage)
  check_language(CXX)
  if(CMAKE_CXX_COMPILER)
    enable_language(CXX)
    add_executable(test_cpp tests/test_cpp.cpp)
    target_link_libraries(test_cpp PRIVATE chirpmodem)
    set_target_properties(test_cpp PROPERTIES CXX_STANDARD 11)
    add_test(NAME cpp COMMAND test_cpp)
  endif()
endif()

if(CHIRPMODEM_BUILD_EXAMPLES)
  add_executable(loopback examples/loopback.c)
  target_link_libraries(loopback PRIVATE chirpmodem)
  set_target_properties(loopback PROPERTIES C_STANDARD 99)
  if(CHIRPMODEM_BUILD_TESTS)
    add_test(NAME example COMMAND loopback)
  endif()
endif()

# ---------------------------------------------------------------- install
install(TARGETS chirpmodem chirpmodem_static EXPORT chirpmodemTargets
  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
  PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
install(FILES include/chirpmodem.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
install(EXPORT chirpmodemTargets NAMESPACE chirpmodem::
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/chirpmodem)
configure_package_config_file(cmake/chirpmodemConfig.cmake.in
  ${CMAKE_CURRENT_BINARY_DIR}/chirpmodemConfig.cmake
  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/chirpmodem)
write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/chirpmodemConfigVersion.cmake
  COMPATIBILITY SameMinorVersion)
install(FILES ${CMAKE_CURRENT_BINARY_DIR}/chirpmodemConfig.cmake
  ${CMAKE_CURRENT_BINARY_DIR}/chirpmodemConfigVersion.cmake
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/chirpmodem)
# prefix relative to <libdir>/pkgconfig, so the tree can be installed anywhere
file(RELATIVE_PATH PC_PREFIX_REL "/p/${CMAKE_INSTALL_LIBDIR}/pkgconfig" "/p")
configure_file(chirpmodem.pc.in ${CMAKE_CURRENT_BINARY_DIR}/chirpmodem.pc @ONLY)
install(FILES ${CMAKE_CURRENT_BINARY_DIR}/chirpmodem.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
install(FILES LICENSE DESTINATION ${CMAKE_INSTALL_DATADIR}/doc/chirpmodem)
