From 3634c263c7e4064be1a915e6e96c065e5271bf62 Mon Sep 17 00:00:00 2001
From: Daniel Peter Chokola <dan.chokola@gmail.com>
Date: Mon, 27 Feb 2023 21:26:34 -0500
Subject: [PATCH] introduce pre-build script to add automatic build-time
 versioning

---
 .cproject     |   4 +-
 .gitignore    |   1 +
 pre-build.cmd | 240 ++++++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 243 insertions(+), 2 deletions(-)
 create mode 100755 pre-build.cmd

diff --git a/.cproject b/.cproject
index 1698297..8ff1d4c 100644
--- a/.cproject
+++ b/.cproject
@@ -14,7 +14,7 @@
 				</extensions>
 			</storageModule>
 			<storageModule moduleId="cdtBuildSystem" version="4.0.0">
-				<configuration artifactExtension="elf" artifactName="${ProjName}" buildArtefactType="org.eclipse.cdt.build.core.buildArtefactType.exe" buildProperties="org.eclipse.cdt.build.core.buildArtefactType=org.eclipse.cdt.build.core.buildArtefactType.exe,org.eclipse.cdt.build.core.buildType=org.eclipse.cdt.build.core.buildType.debug" cleanCommand="rm -rf" description="" id="com.st.stm32cube.ide.mcu.gnu.managedbuild.config.exe.debug.1922127164" name="Debug" parent="com.st.stm32cube.ide.mcu.gnu.managedbuild.config.exe.debug">
+				<configuration artifactExtension="elf" artifactName="${ProjName}" buildArtefactType="org.eclipse.cdt.build.core.buildArtefactType.exe" buildProperties="org.eclipse.cdt.build.core.buildArtefactType=org.eclipse.cdt.build.core.buildArtefactType.exe,org.eclipse.cdt.build.core.buildType=org.eclipse.cdt.build.core.buildType.debug" cleanCommand="rm -rf" description="" id="com.st.stm32cube.ide.mcu.gnu.managedbuild.config.exe.debug.1922127164" name="Debug" parent="com.st.stm32cube.ide.mcu.gnu.managedbuild.config.exe.debug" prebuildStep="../pre-build.cmd">
 					<folderInfo id="com.st.stm32cube.ide.mcu.gnu.managedbuild.config.exe.debug.1922127164." name="/" resourcePath="">
 						<toolChain id="com.st.stm32cube.ide.mcu.gnu.managedbuild.toolchain.exe.debug.592962166" name="MCU ARM GCC" superClass="com.st.stm32cube.ide.mcu.gnu.managedbuild.toolchain.exe.debug">
 							<option id="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.target_mcu.1135380319" name="MCU" superClass="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.target_mcu" useByScannerDiscovery="true" value="STM32F401CCUx" valueType="string"/>
@@ -24,7 +24,7 @@
 							<option id="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.floatabi.813197789" name="Floating-point ABI" superClass="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.floatabi" useByScannerDiscovery="true" value="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.floatabi.value.hard" valueType="enumerated"/>
 							<option id="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.target_board.255620478" name="Board" superClass="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.target_board" useByScannerDiscovery="false" value="genericBoard" valueType="string"/>
 							<option id="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.defaults.752622469" name="Defaults" superClass="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.defaults" useByScannerDiscovery="false" value="com.st.stm32cube.ide.common.services.build.inputs.revA.1.0.5 || Debug || true || Executable || com.st.stm32cube.ide.mcu.gnu.managedbuild.option.toolchain.value.workspace || STM32F401CCUx || 0 || 0 || arm-none-eabi- || ${gnu_tools_for_stm32_compiler_path} || ../Core/Inc | ../Drivers/STM32F4xx_HAL_Driver/Inc | ../Drivers/STM32F4xx_HAL_Driver/Inc/Legacy | ../Drivers/CMSIS/Device/ST/STM32F4xx/Include | ../Drivers/CMSIS/Include | ../USB_DEVICE/App | ../USB_DEVICE/Target | ../Middlewares/ST/STM32_USB_Device_Library/Core/Inc | ../Middlewares/ST/STM32_USB_Device_Library/Class/CDC/Inc ||  ||  || USE_HAL_DRIVER | STM32F401xC ||  || Drivers | Core/Startup | Middlewares | Core | USB_DEVICE ||  ||  || ${workspace_loc:/${ProjName}/STM32F401CCUX_FLASH.ld} || true || NonSecure ||  || secure_nsclib.o ||  || None || " valueType="string"/>
-							<option id="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.nanoprintffloat.1376255223" superClass="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.nanoprintffloat" useByScannerDiscovery="false" value="true" valueType="boolean"/>
+							<option id="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.nanoprintffloat.1376255223" name="Use float with printf from newlib-nano (-u _printf_float)" superClass="com.st.stm32cube.ide.mcu.gnu.managedbuild.option.nanoprintffloat" useByScannerDiscovery="false" value="true" valueType="boolean"/>
 							<targetPlatform archList="all" binaryParser="org.eclipse.cdt.core.ELF" id="com.st.stm32cube.ide.mcu.gnu.managedbuild.targetplatform.1998061963" isAbstract="false" osList="all" superClass="com.st.stm32cube.ide.mcu.gnu.managedbuild.targetplatform"/>
 							<builder buildPath="${workspace_loc:/hothouse-mon}/Debug" id="com.st.stm32cube.ide.mcu.gnu.managedbuild.builder.766542675" keepEnvironmentInBuildfile="false" managedBuildOn="true" name="Gnu Make Builder" parallelBuildOn="true" parallelizationNumber="optimal" superClass="com.st.stm32cube.ide.mcu.gnu.managedbuild.builder"/>
 							<tool id="com.st.stm32cube.ide.mcu.gnu.managedbuild.tool.assembler.2104471420" name="MCU GCC Assembler" superClass="com.st.stm32cube.ide.mcu.gnu.managedbuild.tool.assembler">
diff --git a/.gitignore b/.gitignore
index 878ed76..c791daa 100644
--- a/.gitignore
+++ b/.gitignore
@@ -1,4 +1,5 @@
 /.settings
 /Debug
 /*.launch
+/Core/Inc/config.h
 
diff --git a/pre-build.cmd b/pre-build.cmd
new file mode 100755
index 0000000..e4f424f
--- /dev/null
+++ b/pre-build.cmd
@@ -0,0 +1,240 @@
+:<<"::CMDLITERAL"
+@ECHO OFF
+GOTO :CMDSCRIPT
+::CMDLITERAL
+
+echo -n Finding git revision...
+gitrev="$(git describe --always --dirty --tags 2>/dev/null)"
+echo ${gitrev}
+
+gitrev_num="$(git describe --always 2>/dev/null)"
+
+echo -n Finding number of git commits...
+gitnum_commits="$(git rev-list --count HEAD 2>/dev/null)"
+echo ${gitnum_commits}
+
+gitrev_dirty=0
+if [ ! "${gitrev}" ]; then
+	gitrev_num=0
+elif [ ! "${gitrev_num}" ]; then
+	case "${gitrev}" in
+		*-dirty)
+		gitrev_dirty=1
+	esac
+	gitrev_num="${gitrev//-dirty}"
+else
+	case "${gitrev}" in
+		*-dirty)
+		gitrev_dirty=1
+	esac
+fi
+
+if [ -n "${gitrev}" ]; then
+	version="git-${gitrev}"
+else
+	version="unknown"
+fi
+
+IFS=, read -r cyear cyr cmonth cdoy cday chour cmin csec <<EOF
+$(git show --pretty="format:%cd" --no-patch --date="format:%#Y,%#y,%#m,%#j,%#d,%#H,%#M,%#S")
+EOF
+IFS=, read -r year yr month doy day hour min sec <<EOF
+$(date +%#Y,%#y,%#m,%#j,%#d,%#H,%#M,%#S)
+EOF
+
+cat >../Core/Inc/config.h <<EOF
+/* config.h - autogenerated at build-time -- do not edit */
+
+#ifndef _CONFIG_H_
+#define _CONFIG_H_
+
+/* Git */
+#define GIT (1)
+#define GIT_REV "${gitrev}"
+#define GIT_REV_NUMERIC (0x${gitrev_num})
+#define GIT_REV_DIRTY (${gitrev_dirty})
+#define GIT_NUM_COMMITS (${gitnum_commits})
+
+#define SCM_VERSION "${version}"
+
+/* Commit Date & Time */
+#define COMMIT_YEAR (${cyear})
+#define COMMIT_YR (${cyr})
+#define COMMIT_MONTH (${cmonth})
+#define COMMIT_DOY (${cdoy})
+#define COMMIT_DAY (${cday})
+#define COMMIT_HOUR (${chour})
+#define COMMIT_MINUTE (${cmin})
+#define COMMIT_SECOND (${csec})
+
+/* Build Date & Time */
+#define BUILD_YEAR (${year})
+#define BUILD_YR ($(expr $year % 100))
+#define BUILD_MONTH (${month})
+#define BUILD_DOY (${doy})
+#define BUILD_DAY (${day})
+#define BUILD_HOUR (${hour})
+#define BUILD_MINUTE (${min})
+#define BUILD_SECOND (${sec})
+
+#endif /* _CONFIG_H_ */
+EOF
+
+exit $?
+
+:CMDSCRIPT
+SETLOCAL EnableDelayedExpansion
+REM Store a newline in this variable.
+REM N.B.: The two blank lines are necessary!
+SET _NL=^
+
+
+REM Find Git revision and append '-dirty' if there are uncommitted changes.
+<NUL set /p _dummy=Finding git revision...
+FOR /F "USEBACKQ tokens=*" %%a IN (`git describe --always --dirty --tags 2^> NUL`) DO (
+	SET "gitrev=%%a"
+)
+ECHO  "%gitrev%"
+
+FOR /F "USEBACKQ tokens=*" %%a IN (`git describe --always`) DO (
+	SET "gitrev_num=%%a"
+	SET "gitrev_dirty=0"
+)
+
+REM Find number of Git commits.
+<NUL set /p _dummy=Finding number of git commits...
+FOR /F "USEBACKQ tokens=*" %%a IN (`git rev-list --count HEAD 2^> NUL`) DO (
+	SET "gitnum_commits=%%a"
+)
+ECHO  "%gitnum_commits%"
+
+REM Store the revision in a version variable and prepend the SCM.
+IF NOT "x%gitrev%" == "x" (
+	SET "version=git-%gitrev%"
+) ELSE (
+	SET "version=unknown"
+)
+ECHO Set version="%version%"
+
+REM Set numerical and dirty bits appropriately.
+REM For git:
+IF "x%gitrev%" == "x" (
+	SET "gitrev_num=0"
+	SET "gitrev_dirty=0"
+) ELSE IF "x%gitrev_num%" == "x" (
+	IF NOT "x!gitrev:-dirty=!" == "x%gitrev%" (
+		SET "gitrev_dirty=1"
+	) ELSE (
+		SET "gitrev_dirty=0"
+	)
+	SET "gitrev_num=%gitrev:-dirty=%"
+) ELSE (
+	IF NOT "x!gitrev:-dirty=!" == "x%gitrev%" (
+		SET "gitrev_dirty=1"
+	) ELSE (
+		SET "gitrev_dirty=0"
+	)
+)
+
+REM Commit Date Information
+IF "x%gitrev%" neq "x" (
+	<NUL set /p _dummy=Finding git commit date and time...
+	FOR /F "USEBACKQ tokens=1-8 delims=^," %%m IN (`git show --pretty^="format:%%cd" --no-patch --date^="format:%%#Y,%%#y,%%#m,%%#j,%%#d,%%#H,%%#M,%%#S" 2^> NUL`) DO (
+		SET "cyear=%%m"
+		SET "cyr=%%n"
+		SET "cmonth=%%o"
+		SET "cdoy=%%p"
+		SET "cday=%%q"
+		SET "chour=%%r"
+		SET "cmin=%%s"
+		SET "csec=%%t"
+	)
+	ECHO "!cyear!/!cmonth!/!cday! !chour!:!cmin!:!csec!"
+)
+
+REM Build Date Information
+<NUL set /p _dummy=Finding build date and time...
+SET /A i=0, sum=0
+REM accumulate day-offSETs for every month in %accum[1...12]%
+for %%a in (31 28 31 30 31 30 31 31 30 31 30 31) do (
+   SET /A i+=1
+   SET /A accum[!i!]=sum, sum+=%%a
+)
+
+REM apply date value from date command
+REM date is locale-specific!
+FOR /F "USEBACKQ tokens=2-4 delims=/ " %%a IN (`DATE /T 2^> NUL`) DO (
+	SET "CurrDate=%%c%%b%%a"
+)
+REM WMIC retrieves current system date/time in standardized format;
+REM parse its output by FOR /F, then store it in %CurrDate%
+FOR /F "USEBACKQ tokens=2 delims==" %%a IN (`wmic OS GET LocalDateTime /VALUE 2^> NUL ^| FIND "=" 2^> NUL`) DO (
+	SET "CurrDate=%%a"
+)
+
+REM extract %year%, %month%, and %day%
+SET /A year=1%CurrDate:~0,4%-10000, month=1%CurrDate:~4,2%-100, day=1%CurrDate:~6,2%-100
+REM extract %hour%, %minute%, and %second%
+SET /A hour=1%CurrDate:~8,2%-100, minute=1%CurrDate:~10,2%-100, second=1%CurrDate:~12,2%-100
+REM compute several moduli needed for determining whether year is leap year
+SET /A yearMOD4=%CurrDate:~0,4% %% 4
+SET /A yearMOD100=%CurrDate:~0,4% %% 100, yearMOD400=%CurrDate:~0,4% %% 400
+REM calculate %dayOfYear% as it were not a leap year
+SET /A dayOfYear=!accum[%month%]!+day
+REM adapt %dayOfYear% only in case %month% is past February (29th)
+IF %month% gtr 2 (
+    REM check for leap year and adapt %dayOfYear% accordingly
+    IF %yearMOD4% equ 0 SET /A dayOfYear+=1
+    IF %yearMOD400% neq 0 IF %yearMOD100% equ 0 SET /A dayOfYear-=1
+)
+REM return result
+set "y0=000%year%"
+set "n0=0%month%"
+set "d0=0%day%"
+set "h0=0%hour%"
+set "m0=0%minute%"
+set "s0=0%second%"
+echo "!y0:~-4!/!n0:~-2!/!d0:~-2! !h0:~-2!:!m0:~-2!:!s0:~-2!"
+
+REM Fill in the blanks.
+SET config=/* config.h - autogenerated at build-time -- do not edit */!_NL!^
+!_NL!^
+#ifndef _CONFIG_H_!_NL!^
+#define _CONFIG_H_!_NL!^
+!_NL!^
+/* Git */
+IF "x%gitrev%" == "x" SET config=!config!!_NL!^#undef GIT!_NL!^
+
+
+IF NOT "x%gitrev%" == "x" SET config=!config!!_NL!^#define GIT (1)!_NL!^
+#define GIT_REV "%gitrev%"!_NL!^
+#define GIT_REV_NUMERIC (0x%gitrev_num%)!_NL!^
+#define GIT_REV_DIRTY (%gitrev_dirty%)!_NL!^
+#define GIT_NUM_COMMITS (%gitnum_commits%)!_NL!^
+
+
+SET config=!config!#define SCM_VERSION "%version%"!_NL!^
+!_NL!^
+/* Commit Date ^& Time */!_NL!^
+#define COMMIT_YEAR (%cyear%)!_NL!^
+#define COMMIT_YR (%cyr%)!_NL!^
+#define COMMIT_MONTH (%cmonth%)!_NL!^
+#define COMMIT_DOY (%cdoy%)!_NL!^
+#define COMMIT_DAY (%cday%)!_NL!^
+#define COMMIT_HOUR (%chour%)!_NL!^
+#define COMMIT_MINUTE (%cmin%)!_NL!^
+#define COMMIT_SECOND (%csec%)!_NL!^
+!_NL!^
+/* Build Date ^& Time */!_NL!^
+#define BUILD_YEAR (%year%)!_NL!^
+#define BUILD_YR (%yearMOD100%)!_NL!^
+#define BUILD_MONTH (%month%)!_NL!^
+#define BUILD_DOY (%dayOfYear%)!_NL!^
+#define BUILD_DAY (%day%)!_NL!^
+#define BUILD_HOUR (%hour%)!_NL!^
+#define BUILD_MINUTE (%minute%)!_NL!^
+#define BUILD_SECOND (%second%)!_NL!^
+!_NL!^
+#endif /* _CONFIG_H_ */
+
+echo !config! > ..\Core\Inc\config.h