project(demodchirpmodem)

# libchirpmodem: found through its CMake package. A local install (for example
# cmake --install build --prefix ~/.local) is found through CHIRPMODEM_DIR,
# the CMake prefix path, or the default hint below.
set(CHIRPMODEM_DIR "" CACHE PATH "Install prefix of libchirpmodem")
find_package(chirpmodem 0.1 REQUIRED
    HINTS ${CHIRPMODEM_DIR} $ENV{HOME}/.local
)

set(demodchirpmodem_SOURCES
    chirpmodemdemod.cpp
    chirpmodemdemodsettings.cpp
    chirpmodemdemodbaseband.cpp
    chirpmodemdemodsink.cpp
    chirpmodemmessages.cpp
    chirpmodemdemodplugin.cpp
    chirpmodemdemodwebapiadapter.cpp
)

set(demodchirpmodem_HEADERS
    chirpmodemdemod.h
    chirpmodemdemodsettings.h
    chirpmodemdemodbaseband.h
    chirpmodemdemodsink.h
    chirpmodemmessages.h
    chirpmodemdemodplugin.h
    chirpmodemdemodwebapiadapter.h
)

include_directories(
    ${CMAKE_SOURCE_DIR}/swagger/sdrangel/code/qt5/client
)

if(NOT SERVER_MODE)
    set(demodchirpmodem_SOURCES
        ${demodchirpmodem_SOURCES}
        chirpmodemdemodgui.cpp
        chirpmodemdemodgui.ui
    )
    set(demodchirpmodem_HEADERS
        ${demodchirpmodem_HEADERS}
        chirpmodemdemodgui.h
    )

    set(TARGET_NAME ${PLUGINS_PREFIX}demodchirpmodem)
    set(TARGET_LIB "Qt::Widgets")
    set(TARGET_LIB_GUI "sdrgui")
    set(INSTALL_FOLDER ${INSTALL_PLUGINS_DIR})
else()
    set(TARGET_NAME ${PLUGINSSRV_PREFIX}demodchirpmodemsrv)
    set(TARGET_LIB "")
    set(TARGET_LIB_GUI "")
    set(INSTALL_FOLDER ${INSTALL_PLUGINSSRV_DIR})
endif()

if(NOT Qt6_FOUND)
    add_library(${TARGET_NAME} ${demodchirpmodem_SOURCES})
else()
    qt_add_plugin(${TARGET_NAME} CLASS_NAME ChirpModemDemodPlugin)
    target_sources(${TARGET_NAME} PRIVATE ${demodchirpmodem_SOURCES})
endif()

if(NOT BUILD_SHARED_LIBS)
    set_property(GLOBAL APPEND PROPERTY STATIC_PLUGINS_PROPERTY ${TARGET_NAME})
endif()

# The static library is position independent, so the plugin carries the modem
# and needs no library path at run time.
target_link_libraries(${TARGET_NAME} PRIVATE
    Qt::Core
    ${TARGET_LIB}
    sdrbase
    ${TARGET_LIB_GUI}
    chirpmodem::chirpmodem_static
)

install(TARGETS ${TARGET_NAME} DESTINATION ${INSTALL_FOLDER})

# Install debug symbols
if (WIN32)
    install(FILES $<TARGET_PROPERTY:${TARGET_NAME},RUNTIME_OUTPUT_DIRECTORY>/${TARGET_NAME}stripped.pdb CONFIGURATIONS Release DESTINATION ${INSTALL_FOLDER} RENAME ${TARGET_NAME}.pdb )
    install(FILES $<TARGET_PDB_FILE:${TARGET_NAME}> CONFIGURATIONS Debug RelWithDebInfo DESTINATION ${INSTALL_FOLDER} )
endif()
